Performance comparison between Axial and Radial Orientations

Key definitions:

1. Axial Orientation:

Mounting the Magnet at the free end face of the Shaft, and letting the motor to rotate. Now, when it is rotating, you will bring the AS5600 in perpendicular to the axis of rotation.

flowchart LR
    subgraph h[" "]
    direction LR
        M[Motor] -->|"↻ rotates"| S[Shaft]
    end
    subgraph v[" "]
        AS[" A <br> S <br> 5 <br> 6 <br> 0 <br> 0 "]
    end
    h -.- |"end face"| MAG[M<br>a<br>g<br>n<br>e<br>t] -.- |"Sensor is <br>⊥ to rotational axis"| v
    

2. Radial Orientation:

Mounting the magnet at a tangential curvature of the shaft, (in our case, for n20 motors, we get D-shaft, which has a flat surface.) and letting the motor to rotate. Now, when it is rotating, you will bring the AS5600 in radial offset, in parallel to the axis of rotation.

flowchart LR
subgraph h[" "]
    direction RL
    M[Motor] -->|"↻ rotates"| S[Shaft] 
    end

flowchart TD
    subgraph v[" "]
        direction TD
        MAG[Magnet]
    end
    subgraph h[" "]
        MAG -.-|"Sensor is ∥ to the <br>rotational axis <br> of the shaft."| AS[AS5600]
    end
    style v fill:none,stroke:none

Experiment:

I Tried experimenting with 4 different orientations, by taking a sample of data with Mounting:

1. Axial Magnet in Axial Orientation Full Log Here
2. Axial Magnet in radial Orientation Full Log Here
3. Diametric Magnet in Axial Orientation Full Log Here
4. Diamteric Magnet in Radial Orientation Full Log Here

I used the same motor, same battery, same code, but - I got naughty and tried varying the RPM by using 203 (20k) variable resistor.

Note, I am using Arduino for now, but for production, I will be using ESP IDF. Using Arduino because it helps me with conceptual clarity faster.

Code:

/*
This code is for measuring RPM, and Angle of a motor shaft. 
NOTE: This Source is for reading values that has
a D-Shaft with all the above 4 configuartions.
In my configuration, the bot is placed around
2-3mm away from the nearest rotating magnet attached to shaft. 
Video reference: https://www.instagram.com/p/DY_T-oABRys/
*/
#include <Wire.h>

#define AS5600_ADDR    0x36
#define RAW_ANGLE_HIGH 0x0C
#define RAW_ANGLE_LOW  0x0D

const float COUNTS_PER_REV      = 4096.0;
const int   SAMPLE_INTERVAL_US  = 100;// For every 0.1ms, take sample. 

// State
int16_t  lastAngle       = 0;
unsigned long lastTime   = 0;

// Revolution period RPM
float    rpm                = 0.0;
unsigned long lastRevTime   = 0;
bool     revStarted         = false;
int16_t  prevAngle          = 0;
long     accumDelta         = 0;//accumulated counts since last full rev

int16_t readRawAngle() {
  Wire.beginTransmission(AS5600_ADDR);
  Wire.write(RAW_ANGLE_HIGH);
  Wire.endTransmission(false);
  Wire.requestFrom(AS5600_ADDR, 2);
  int16_t high = Wire.read();
  int16_t low  = Wire.read();
  return ((high << 8) | low) & 0x0FFF;
}

void setup() {
  // I also have 2 I2Cs, and Just wanted
  // to confirm just before running the loop.
  // one for AS5600 and another for SSD1306 OLED.
  Serial.begin(115200);
  while (!Serial);
  delay(1000);
  Wire.begin(5, 6); // my I2C pins.

  Serial.println("Scanning I2C...");
  for (byte addr = 1; addr < 127; addr++) {
    Wire.beginTransmission(addr);
    if (Wire.endTransmission() == 0) {
      Serial.print("Device found at 0x");
      Serial.println(addr, HEX);
    }
  }
  Serial.println("AS5600 Ready.");
  Serial.println("timestamp_us,angle_deg,rpm");

  lastAngle    = readRawAngle();
  prevAngle    = lastAngle;
  lastTime     = micros();
  lastRevTime  = micros();
  revStarted   = true;
}

void loop() {
  unsigned long now = micros();

  if (now - lastTime >= SAMPLE_INTERVAL_US) {
    int16_t currentAngle = readRawAngle();

    // Angle in degrees
    float degrees = (currentAngle / COUNTS_PER_REV) * 360.0;

    // Revolution period RPM
    int16_t delta = currentAngle - prevAngle;
    if (delta >  2048) delta -= 4096; // wraparound CW
    if (delta < -2048) delta += 4096; // wraparound CCW

    accumDelta += delta;

    // Detect full revolution: +4096 counts = 1 full CW rev
    //                         -4096 counts = 1 full CCW rev
    if (accumDelta >= 4096) {
      unsigned long revPeriodUs = now - lastRevTime;
      rpm         = 60000000.0 / revPeriodUs; // CW positive
      lastRevTime = now;
      accumDelta -= 4096;
    } else if (accumDelta <= -4096) {
      unsigned long revPeriodUs = now - lastRevTime;
      rpm         = -60000000.0 / revPeriodUs; // CCW negative
      lastRevTime = now;
      accumDelta += 4096;
    }

    // Log
    Serial.print(now);
    Serial.print(",");
    Serial.print(degrees, 2);
    Serial.print(",");
    Serial.println(rpm, 2);

    prevAngle = currentAngle;
    lastTime  = now;
    //continue loop.
  }
}

Results and conclusions:

From this experiment, I have learned that it is possible to get accurate angles to track the position of shaft only when:

1. Axial Magnet is in radial Orientation
2. Diametric Magnet is in Axial Orientation

the other 2 methods will not give position tracking.

1. Diametric Magnet in Axial Orientation
2. Diamteric Magnet in Radial Orientation

Extract of the data in Table

I started writing this log at June 6, 2026 7:12PM AWST and now, at the time of finishing, it is June 7, 2026, 12:10AM. I will continue tomorrow. Thank you for reading! ♥️